**Longitudinal Story Time: Practice Thinking about Time-Invariant Predictors**

1. Kelly Farquharsen (UNL; now at Emory College): Early Babbling and Later Reading

* 12 children; 8 occasions at 3-month intervals from ages 9–30 months
* Outcome is constant–vowel (CV) ratio; letter identification also measured at 72 months only
* Research Question: Does growth in speech complexity predict later pre-reading skills?
* Primary Model for CV ratio

**TITLE "Saturated Means, Random Intercept";**

**PROC MIXED DATA=work.stacked NOCLPRINT NOITPRINT COVTEST METHOD=REML;**

**CLASS SubjectID age;**

**MODEL CVRatio = age / SOLUTION DDFM=KR;**

**RANDOM INTERCEPT / TYPE=UN SUBJECT=SubjectID;**

**LSMEANS age;**

**RUN;**

**TITLE "Effects of Letter ID on intercept, linear, and quadratic";**

**PROC MIXED DATA=work.stacked NOCLPRINT NOITPRINT COVTEST METHOD=REML;**

**CLASS SubjectID;**

**MODEL CVRatio = age12 age12\*age12 let35 let35\*age12 let35\*age12\*age12 / SOLUTION DDFM=KR;**

**RANDOM INTERCEPT / TYPE=UN SUBJECT=SubjectID;**

**\* Simple effects of letter ID by age;**

**ESTIMATE "Let Effect AT MONTH 9" let35 1 let35\*age12 -3 let35\*age12\*age12 9;**

**ESTIMATE "Let Effect AT MONTH 12" let35 1 let35\*age12 0 let35\*age12\*age12 0;**

**ESTIMATE "Let Effect AT MONTH 15" let35 1 let35\*age12 3 let35\*age12\*age12 9;**

**ESTIMATE "Let Effect AT MONTH 18" let35 1 let35\*age12 6 let35\*age12\*age12 36;**

**ESTIMATE "Let Effect AT MONTH 21" let35 1 let35\*age12 9 let35\*age12\*age12 81;**

**ESTIMATE "Let Effect AT MONTH 24" let35 1 let35\*age12 12 let35\*age12\*age12 144;**

**ESTIMATE "Let Effect AT MONTH 27" let35 1 let35\*age12 15 let35\*age12\*age12 225;**

**ESTIMATE "Let Effect AT MONTH 30" let35 1 let35\*age12 18 let35\*age12\*age12 324;**

**\* Values to plot for -1, +1 SD;**

**ESTIMATE "INTERCEPT AT MONTH 9 for Let=32" intercept 1 age12 -3 age12\*age12 9 let35 -3 let35\*age12 9 let35\*age12\*age12 -27;**

**ESTIMATE "INTERCEPT AT MONTH 12 for Let=32" intercept 1 age12 0 age12\*age12 0 let35 -3 let35\*age12 0 let35\*age12\*age12 0;**

**ESTIMATE "INTERCEPT AT MONTH 15 for Let=32" intercept 1 age12 3 age12\*age12 9 let35 -3 let35\*age12 -9 let35\*age12\*age12 -27;**

**ESTIMATE "INTERCEPT AT MONTH 18 for Let=32" intercept 1 age12 6 age12\*age12 36 let35 -3 let35\*age12 -18 let35\*age12\*age12 -108;**

**ESTIMATE "INTERCEPT AT MONTH 21 for Let=32" intercept 1 age12 9 age12\*age12 81 let35 -3 let35\*age12 -27 let35\*age12\*age12 -243;**

**ESTIMATE "INTERCEPT AT MONTH 24 for Let=32" intercept 1 age12 12 age12\*age12 144 let35 -3 let35\*age12 -36 let35\*age12\*age12 -432;**

**ESTIMATE "INTERCEPT AT MONTH 27 for Let=32" intercept 1 age12 15 age12\*age12 225 let35 -3 let35\*age12 -45 let35\*age12\*age12 -675;**

**ESTIMATE "INTERCEPT AT MONTH 30 for Let=32" intercept 1 age12 18 age12\*age12 324 let35 -3 let35\*age12 -54 let35\*age12\*age12 -972;**

**ESTIMATE "INTERCEPT AT MONTH 9 for Let=38" intercept 1 age12 -3 age12\*age12 9 let35 3 let35\*age12 -9 let35\*age12\*age12 27;**

**ESTIMATE "INTERCEPT AT MONTH 12 for Let=38" intercept 1 age12 0 age12\*age12 0 let35 3 let35\*age12 0 let35\*age12\*age12 0;**

**ESTIMATE "INTERCEPT AT MONTH 15 for Let=38" intercept 1 age12 3 age12\*age12 9 let35 3 let35\*age12 9 let35\*age12\*age12 27;**

**ESTIMATE "INTERCEPT AT MONTH 18 for Let=38" intercept 1 age12 6 age12\*age12 36 let35 3 let35\*age12 18 let35\*age12\*age12 108;**


**ESTIMATE "INTERCEPT AT MONTH 21 for Let=38" intercept 1 age12 9 age12\*age12 81 let35 3 let35\*age12 27 let35\*age12\*age12 243;**


**ESTIMATE "INTERCEPT AT MONTH 24 for Let=38" intercept 1 age12 12 age12\*age12 144 let35 3 let35\*age12 36 let35\*age12\*age12 432;**

**ESTIMATE "INTERCEPT AT MONTH 27 for Let=38" intercept 1 age12 15 age12\*age12 225 let35 3 let35\*age12 45 let35\*age12\*age12 675;**

**ESTIMATE "INTERCEPT AT MONTH 30 for Let=38" intercept 1 age12 18 age12\*age12 324 let35 3 let35\*age12 54 let35\*age12\*age12 972;**

**RUN;**

****

1. ****Kathleen Kelsey Earnest (UNL, now at KU): Growth in Motor Inhibition and Delayed Gratification in Preschoolers

* 379 children; 4 occasions at 9-month intervals from ages 3.0–5.25 years
* 26% of mothers smoked at least once during pregnancy
* Two outcomes from snack delay task: motor movement and eat snack: yes/no?
* Research Questions:
  + What is the effect of prenatal tobacco exposure on each outcome?
  + Do these smoking effects vary by child gender?
  + To what extent do these effects remain after controlling for SES?
* Primary Model for Motor

**TITLE "Effects of Exposure and Gender on Intercept and Linear Change ";**

**PROC MIXED DATA=work.stacked NOCLPRINT NOITPRINT COVTEST METHOD=REML;**

**CLASS SubjectID age;**

**MODEL motor = age4|exp|girl@3 / SOLUTION DDFM=KR;**

**RANDOM INTERCEPT age4 / GCORR TYPE=UN SUBJECT=SubjectID;**

**\* Simple effects of exposure for boys;**

**ESTIMATE "Exposure Effect at 36 months (wave 1) for Boys" exp 1 exp\*age4 -3 exp\*girl 0 exp\*girl\*age4 0;**


**ESTIMATE "Exposure Effect at 45 months (wave 2) for Boys" exp 1 exp\*age4 -2 exp\*girl 0 exp\*girl\*age4 0;**

**ESTIMATE "Exposure Effect at 54 months (wave 3) for Boys" exp 1 exp\*age4 -1 exp\*girl 0 exp\*girl\*age4 0;**

**ESTIMATE "Exposure Effect at 63 months (wave 4) for Boys" exp 1 exp\*age4 0 exp\*girl 0 exp\*girl\*age4 0;**

**ESTIMATE "Exposure Effect on Linear Slope for Boys" exp\*age4 1 exp\*girl\*age4 0;**

**RUN;**

****

1. Treatment Effects in Persons with Severe Mental Illness

* ~24 persons initially, down to 12 by end of study; 3 occasions; multiple outcomes of mental health
* Treatment group occasions = before, after, follow-up; Wait-list control = before, before, after
* Research Question: Does treatment work?
* Primary model for the means using first occasion as time 0 and wait-list control as reference

Wave 1 Wave 2 Wave 3

**Treated** **Wait-List Control**

**\* Creating piecewise slopes;**

**DATA work.stacked; SET work.stacked;**

**IF wave=1 THEN DO; slope1=0; slope2=0; END;**

**IF wave=2 THEN DO; slope1=1; slope2=0; END;**

**IF wave=3 THEN DO; slope1=1; slope2=1; END;**

**RUN;**

**TITLE "Effects of Treatment on Change";**

**PROC MIXED DATA=work.stacked NOCLPRINT NOITPRINT COVTEST METHOD=REML;**

**CLASS Subject wave;**

**MODEL health = slope1|treat@2 slope2|treat@2 / SOLUTION DDFM=KR;**

**REPEATED wave / RCORR TYPE=UN SUBJECT=Subject;**

**\* Simple effects of group;**

**ESTIMATE "Treat Effect at Wave 1" treat 1 treat\*slope1 0 treat\*slope2 0;**

**ESTIMATE "Treat Effect at Wave 2" treat 1 treat\*slope1 1 treat\*slope2 0;**

**ESTIMATE "Treat Effect at Wave 3" treat 1 treat\*slope1 1 treat\*slope2 1;**

**ESTIMATE "Slope1 for Wait Group" slope1 1 treat\*slope1 0;**

**ESTIMATE "Slope2 for Wait Group" slope2 1 treat\*slope2 0;**

**ESTIMATE "Slope1 for Treat Group" slope1 1 treat\*slope1 1;**

**ESTIMATE "Slope2 for Treat Group" slope2 1 treat\*slope2 1;**


**ESTIMATE "Group Diff in Treatment?" slope2 -1 slope1 1 slope1\*treat 1;**

**RUN;**

Is this model likely to be sufficient?

4. Effects of Remediation on Property Values

* Annual property values for two kinds of homes across 18 years: remediated or not
* Public meeting about need for remediation occurred in year 6; clean-up started in year 14
* Research Question: Did remediation harm property values?
* Example model for the means using first occasion as time 0 and untreated as reference



**\* Creating piecewise slopes;**

**DATA work.stacked; SET work.stacked;**

**\* Continuous slope1 throughout entire study;**

**slope1=year-1;**

**\* Change in intercept and slope after meeting in year 6;**

**IF year LE 6 THEN DO; jump2=0; slope2=0; END;**

**ELSE IF year GT 6 THEN DO; jump2=1; slope2=year-6; END;**

**\* Change in intercept and slope after cleanup in year 14;**

**IF year LE 14 THEN DO; jump3=0; slope3=0; END;**

**ELSE IF year GT 14 THEN DO; jump3=1; slope3=year-14; END;**

**\* Phases;**

**IF year GT 0 AND year LE 6 THEN phase=1;**

**ELSE IF year GT 6 AND year LE 14 THEN phase=2;**

**ELSE IF year GT 14 AND year LE 18 THEN phase=3;**

**RUN;**

**TITLE "Effects of Remediation on Property Values";**

**PROC MIXED DATA=work.stacked NOCLPRINT NOITPRINT COVTEST METHOD=REML;**

**CLASS HouseID year;**

**MODEL value = slope1|treat@2 jump2|treat@2 slope2|treat@2 jump3|treat@2 slope3|treat@2 / SOLUTION DDFM=KR;**

**RANDOM INTERCEPT / TYPE=UN SUBJECT=HouseID;**

**REPEATED year / TYPE=VC SUBJECT=HouseID;**

**RUN;**

Is this model likely to be sufficient?